Robin & Orchid — 12 of 88

Section - Talking To

Talking to is an action applying to one visible thing.

Understand the command "talk" as something new. [Because Conversation Framework defines TALK TO as a synonym for SAY HELLO TO by default.]

Understand "talk to/with [something]" and "speak to/with [something]" and "chat to/with [something]" as talking to.

Does the player mean talking to a person:

it is very likely.

Check talking to when the noun is not a person:

say "[The noun] wouldn't have much to say to you." instead.

Report talking to:

say "[The noun] ignores you."

[This is a terribly dull default message, but ideally each NPC will have their own set of responses in all situations and this one will never show up. I'm putting it in as a sort of failsafe, though.]

Talking vaguely is an action applying to nothing.

[Removed to improve performance:]

[Understand "talking" as a person photo when the action taken of the item described is the action of talking vaguely.]

[Conversation Framework has a concept of "speaking" which is much the same thing as chatty behavior, but I'm nervous about meddling with it in case I break something.]

Talking to is chatty behavior.

Asking something about is chatty behavior.

Telling something about is chatty behavior.

Asking something for is chatty behavior.

Answering something that is chatty behavior.

Requesting something for is chatty behavior.

Imploring something for is chatty behavior.

Quizzing something about is chatty behavior.

Informing something about is chatty behavior.

Saying hello to is chatty behavior.

Saying goodbye to is chatty behavior.

Saying yes is chatty behavior.

Saying no is chatty behavior.

Saying sorry is chatty behavior.

Talking vaguely is chatty behavior.

Giving something to is chatty behavior.

Showing something to is chatty behavior.

Hailing is chatty behavior.

The block saying no rule is not listed in any rulebook.

The block saying yes rule is not listed in any rulebook.

The block saying sorry rule is not listed in any rulebook.

Report saying no:

say "That was a rhetorical question."

Report saying yes:

say "That was a rhetorical question."

Report saying sorry:

if the current interlocutor is a person and the current interlocutor is awake:

say "[The current interlocutor] just gives you a puzzled look, but you feel a little better.";

otherwise:

say "No one responds to your apology, but you feel a little better."

The say goodbye when moving rule is not listed in any rulebook.

Understand "say [any thing] to [someone]" as quizzing it about (with nouns reversed).

[Understand "say [any thing]" as quizzing it about (with nouns reversed).]

[Fixes to Conversation Framework, because its behaviour is a bit weird w/r/t the current interlocutor sometimes.]

Before implicit-conversing when the current interlocutor is nothing or the current interlocutor is not visible (this is the new implicit-conversing needs current interlocutor rule):

let np be the number of visible people who are not the player;

if np is 0, say "There's no one here to talk to.";

if np > 1, say "You need to specify who you want to speak to.";

if np is not 1, stop the action;

let the interlocutor be a random visible person who is not the player;

if the interlocutor is a person begin;

say "(addressing [the interlocutor])";

let sn be the second noun;

implicitly greet the interlocutor;

now the current interlocutor is the interlocutor;

now the second noun is sn;

otherwise ;

say "You're not talking to anyone.";

stop the action;

end if.

The new implicit-conversing needs current interlocutor rule is listed instead of the implicit-conversing needs current interlocutor rule in the before rules.

Before implicit-conversing when the current interlocutor is not visible and the current interlocutor is not nothing (this is the new can't converse with absent interlocutor rule):

let np be the number of visible people who are not the player;

if np is 0:

say "[The current interlocutor] isn't here.";

reset the interlocutor instead.

The new can't converse with absent interlocutor rule is listed instead of the can't converse with absent interlocutor rule in the before rules.

Last after imploring for:

say "[The noun] do[es]n't have any such thing."